home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 023 - Big U Macroworks.dsk / KEYCAT.SETUP.bas < prev    next >
BASIC Source File  |  2019-02-16  |  4KB  |  57 lines
  1. 10  ONERR  GOTO 500
  2. 20 D$ =  CHR$(4):KP = 49152:KR = 49168:Q$ =  CHR$(34):CS =  -958:BP$ =  CHR$(7)
  3. 30  REM <CTRL-M><CTRL-M>CONFIGURATION ADDRESSES<CTRL-M>
  4. 40 SD = 18687: REM   ONLINE DEVICE
  5. 50 RF = 16514: REM  RESET FLAG
  6. 60 C1 = 18539: REM   CONFIG1
  7. 70 C2 = 18617: REM   CONFIG2 
  8. 80 C3 = 19645: REM   CONFIG3
  9. 100  TEXT : HOME : NORMAL : PRINT  CHR$(21)
  10. 110  PRINT "    KEYCAT.80 SETUP PROGRAM"
  11. 120  PRINT "    -----------------------"
  12. 130  PRINT "    COPYRIGHT (C) 1985, RANDY BRANDT"
  13. 140  PRINT "    BEAGLE BROS MICRO SOFTWARE, INC."
  14. 150  VTAB 9: PRINT 
  15. 170  PRINT D$"BLOAD KEYCAT.80,A$4000":LE =  PEEK(48857) +256 * PEEK(48858): IF  PEEK(RF) >1  THEN  PRINT BP$: PRINT "UNRECOGNIZED VERSION OF KEYCAT.80": END 
  16. 180  GOSUB 460: REM  RESET?
  17. 190  GET X$: IF X$ = "Q"  OR X$ = "q"  THEN 550
  18. 195  IF X$ = "U"  OR X$ = "u"  THEN  POKE RF,1: GOTO 220
  19. 200  IF X$ < >"D"  AND X$ < >"d"  THEN  PRINT BP$;: GOTO 190
  20. 210  POKE RF,0
  21. 220  GOSUB 480: REM    SLOT/DRIVE INFO
  22. 230  GET X$: IF X$ =  CHR$(27)  THEN 180
  23. 240  IF X$ = "R"  OR X$ = "r"  THEN  POKE C1,179: POKE C2,179: POKE C3,179: POKE C1 +3,178: POKE C2 +3,178: POKE C3 +3,178:SL = 3:DR = 2: GOTO 330
  24. 250  IF X$ < >"N"  AND X$ < >"n"  THEN  PRINT BP$;: GOTO 230
  25. 260  VTAB 18: PRINT : CALL CS
  26. 270  VTAB 19: PRINT "ENTER NEW SLOT: ";: GET SL$:SL =  VAL(SL$): PRINT SL$: IF SL$ =  CHR$(27)  THEN 220
  27. 280  IF SL <1  OR SL >7  THEN  PRINT BP$;: GOTO 270
  28. 290  VTAB 19: HTAB 20: PRINT "ENTER NEW DRIVE: ";: GET DR$:DR =  VAL(DR$): PRINT DR$: IF DR$ =  CHR$(27)  THEN 270
  29. 300  IF DR <1  OR DR >2  THEN  PRINT BP$;: GOTO 290
  30. 310  VTAB 19: PRINT "PRESS RETURN TO USE SLOT "SL", DRIVE "DR": ";: GET X$: IF X$ < > CHR$(13)  THEN 260
  31. 320  POKE C1,SL +176: POKE C2,SL +176: POKE C3,SL +176: POKE C1 +3,DR +176: POKE C2 +3,DR +176: POKE C3 +3,DR +176: REM <CTRL-J><CTRL-M>
  32. 330 X = ((DR -1) *128) +SL *16: POKE SD,X
  33. 340  VTAB 7: CALL CS: PRINT : PRINT "CURRENT SETUP:": PRINT : PRINT "CONTROL-RESET ";: INVERSE 
  34. 350 X =  PEEK(RF): IF X  THEN  PRINT "ENABLED;": GOTO 370
  35. 360  PRINT "DISABLED;"
  36. 370  NORMAL : PRINT "MENU FILE ON SLOT ";: INVERSE : PRINT SL;: NORMAL : PRINT ", DRIVE ";: INVERSE : PRINT DR;: NORMAL : PRINT "."
  37. 380  PRINT : PRINT "PRESS RETURN TO SAVE KEYCAT.80,": PRINT "OR ESCAPE TO REDO ";
  38. 390  GET X$: IF X$ =  CHR$(27)  THEN 180
  39. 395  IF X$ < > CHR$(13)  THEN 390
  40. 400  VTAB  PEEK(37): HTAB 1: PRINT "SAVING CONFIGURED VERSION...";: CALL CS: PRINT 
  41. 410  PRINT D$"UNLOCK KEYCAT.80"
  42. 411  PRINT D$"BSAVE KEYCAT.80,A$4000,L"LE: PRINT D$"LOCK KEYCAT.80"
  43. 420  HOME : PRINT : PRINT "TYPE "Q$"-KEYCAT.80"Q$" TO GET STARTED.": END 
  44. 430  POKE KR,0: WAIT KP,128: POKE KR,0:X =  PEEK(KP): RETURN 
  45. 440  REM  CONTROL RESET
  46. 450  RETURN 
  47. 460  VTAB 7: PRINT : CALL CS: PRINT "KEYCAT.80 CREATES A FILE CALLED "Q$"MENU"Q$: PRINT "WHICH MAY BE ACTIVATED BY PRESSING": PRINT "CONTROL-RESET OR BY TYPING"Q$"-MENU"Q$".": PRINT 
  48. 470  PRINT "D - DISABLE THE CONTROL-RESET METHOD": PRINT : PRINT "U - USE CONTROL-RESET TO RUN "Q$"MENU"Q$: PRINT 
  49. 475  PRINT "Q - QUIT": PRINT : PRINT "SELECT "Q$"D"Q$", "Q$"U"Q$" OR "Q$"Q"Q$": ";: RETURN 
  50. 480  VTAB 7: PRINT : CALL CS: PRINT "THE MENU FILE IS USUALLY STORED ON": PRINT "THE RAM DISK IN SLOT 3, DRIVE 2.": PRINT : PRINT "IF YOU DON'T HAVE 128K YOU MAY STORE THEFILE ON A FLOPPY. A HARD DISK MAY ALSO  BE SPECIFIED.": PRINT 
  51. 490  PRINT "R - USE RAM DISK (SLOT 3, DRIVE 2)": PRINT : PRINT "N - NEW SLOT/DRIVE SETTINGS": PRINT : PRINT "SELECT "Q$"R"Q$" OR "Q$"N"Q$": ";: RETURN 
  52. 500 ER =  PEEK(222):EL =  PEEK(218) + PEEK(219) *256
  53. 510  IF EL = 170  THEN  VTAB 7: PRINT BP$: PRINT "CAN'T FIND KEYCAT.80; PLEASE": PRINT "INSERT /BIG.U AND PRESS A KEY: ";: GET X$: ON X$ < > CHR$(27) GOTO 170: GOTO 550
  54. 515  IF EL = 410  THEN 411
  55. 520  IF EL = 411  THEN  VTAB 12: PRINT BP$: CALL CS: PRINT "DISK ERROR": PRINT "PRESS RETURN TO TRY AGAIN": PRINT "OR PRESS ESCAPE: ";: GET X$: ON X$ < > CHR$(27) GOTO 411: GOTO 180
  56. 540  POKE 216,0: RESUME 
  57. 550  HOME : PRINT : PRINT "TYPE "Q$"RUN"Q$" TO RESTART."